5 formas de saber tu clave de Windows 10

Conocer nuestra clave de Windows 10 puede ser en ciertas situaciones interesante. No obstante, a diferencia de los ordenadores con Windows 7 preinstalado, los que usan Windows 8 y Windows 10 no tienen la etiqueta de Certificado de Autenticidad (CoA) con la clave de producto.

Esto se debe a que en versiones posteriores a Windows 7 se aplica el estándar OEM Activation 3.0 obligando a los fabricantes a escribir una única clave de producto en el firmware de la BIOS/UEFI con el fin de impedir la activación de copias ilegales.

De hecho, en Windows 10 no es necesaria la activación porque Microsoft ya se ha encargado de registrar un número de identificación de tu hardware para que cuando reinstales el sistema operativo no necesites ingresar el número de serie e inmediatamente tengas Windows 10 activado.

Sin embargo, hay casos en los que tenemos que anotar nuestra clave de Windows 10 por si queremos utilizarla en otro equipo o, por ejemplo, si estamos pensando en actualizar algún componente de nuestro hardware (cambiar la placa base, el disco duro o la tarjeta gráfica puede hacer que la activación de Windows no sea válida).

Afortunadamente, ahora hay muchas aplicaciones especializadas en ver la clave de Windows 10, aunque no todas son compatibles, ya que algunas incluso muestran una licencia incorrecta, pero por lo general, suelen funcionar bastante bien.

Una clave de producto de Windows es un código de 25 caracteres que se usa para activar Windows. Tiene esta apariencia: XXXXX-XXXXX-XXXXX-XXXXX-XXXXX.

Usar ProduKey para ver la clave de producto de Windows 10

Si te gustan las aplicaciones, para encontrar tu licencia de Windows 10 tienes ProduKey de NirSoft. ProduKey es una herramienta muy liviana con la que no solo puedes saber la clave de Windows 10, sino que también puedes ver la clave de Microsoft Office, Exchange Server y SQL Server en caso de que los tengas instalados.

Cómo ver la clave de producto de Windows 10 desde el registro

Como os comentaba, algunos programas no funcionan del todo bien y muestran un número de serie equivocado. Este sencillo script VBS busca nuestra licencia de Windows 10 a través del registro del sistema y la traduce a un formato legible.

El problema de este script es que a veces no es muy preciso, por lo que yo aconsejo valorar antes las demás opciones. Pero ojo, eso no significa que nunca vaya a funcionar bien y que no sea una buena opción. De hecho, yo lo llevo siempre encima en mi disco duro externo o memoria USB. Además, nos permite guardar nuestra clave de Windows 10 en un archivo de texto.

Copia y pega el siguiente código en tu editor de texto favorito y guarda el archivo con formato .vbs.

Option Explicit 

Dim objshell,path,DigitalID, Result 
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID) 
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file 
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData 
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
       	Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0 
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
    
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name 
    UserName = objshell.ExpandEnvironmentStrings("%UserName%") 
    'Create a text file on desktop 
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function

También puedes descargar el script directamente desde este enlace, si lo prefieres.

Una alternativa a este método puede ser el siguiente script que publicó un usuario en la comunidad de Microsoft:

Set WshShell = CreateObject("WScript.Shell")
MsgBox ConvertToKey(WshShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"))

Function ConvertToKey(Key)
Const KeyOffset = 52
i = 28
Chars = "BCDFGHJKMPQRTVWXY2346789"
Do
Cur = 0
x = 14
Do
Cur = Cur * 256
Cur = Key(x + KeyOffset) + Cur
Key(x + KeyOffset) = (Cur \ 24) And 255
Cur = Cur Mod 24
x = x -1
Loop While x >= 0
i = i -1
KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
If (((29 - i) Mod 6) = 0) And (i <> -1) Then
i = i -1
KeyOutput = "-" & KeyOutput
End If
Loop While i >= 0
ConvertToKey = KeyOutput
End Function

En mi caso, el primer script sí que me devuelve la licencia correcta, mientras que el segundo no. Esto puede suceder por varias razones, que pueden ir desde el hardware hasta el tipo de licencia, por lo que es recomendable utilizar ambos para ver si coinciden o no. Si los scripts nos lanzan diferentes claves de producto, podemos guardar y probar ambas en el momento de la instalación de Windows 10. Alguna será la correcta.

Ver tu clave de Windows 10 desde la consola

Si queremos encontrar nuestra clave de Windows 10 sin programas de terceros podemos hacerlo con un simple comando a través de la consola. Abre Símbolo del sistema como administrador y ejecuta el siguiente comando:

wmic path softwarelicensingservice get OA3xOriginalProductKey

Sin embargo, esta manera de recuperar tu licencia de Windows 10 solo funcionará si el equipo es de marca.

Averigua tu clave de Windows 10 desde la PowerShell

Al igual que el método anterior, podemos recuperar nuestra clave de Windows 10 con PowerShell, pero solo funciona si tu ordenador es de marca (HP, Dell, Lenovo, MSI...), de lo contrario, si es montado por piezas, el resultado será nulo. Copia y pega el siguiente código en una ventana de PowerShell y pulsa INTRO.

powershell "(Get-WmiObject -query ‘select * from SoftwareLicensingService’).OA3xOriginalProductKey"

Cuatro maneras, según Microsoft, de obtener tu clave de activación de Windows 10

• Si has comprado tu copia de Windows 10 a través de un distribuidor autorizado, la clave del producto se encuentra en una etiqueta o una tarjeta dentro de la caja en la que se envió.
• Si has comprado un equipo nuevo con Windows 10 preinstalado, la clave del producto está preinstalada en el equipo, incluida con el paquete en la que se envió el equipo o en el Certificado de autenticidad adherido al equipo. El certificado de autenticidad es la etiqueta que suele encontrarse en la base de un portátil, o bien, en la parte lateral o trasera de la caja de un equipo de sobremesa.
• Si has obtenido una copia digital del sitio web de Microsoft, la clave de producto está en el correo electrónico de confirmación que recibiste después de la compra. Si se distribuyó como una licencia digital, no incluye una clave del producto.
• Si has obtenido Windows 10 a partir de una actualización gratuita, deberías tener una licencia digital en lugar de una clave del producto. Para obtener más información sobre las licencias digitales en Windows 10, consulta esta página.

Si te ha gustado 5 formas de saber tu clave de Windows 10 y te gustaría seguir leyendo contenido similar, puedes visitar la categoría Windows. ¡Y no olvides dejar un comentario 🤗!